엑셀 함수 SUM, SUMIF, SUMIFS - 엑셀 합계, 조건에 맞는 합계 구하기

엑셀함수 SUMIF 함수와 SUMIFS 함수에 대해서 알아보겠습니다. 

구글 스프레드시트에서도 동일하게 사용가능합니다

풀어 말하자면 데이터 중 조건을 충족시키는 데이터의 합계를 구하는 것입니다. 

SUMIF 함수는 하나의 단일조건을, SUMIFS함수는 복수의 조건을 충족하는 합계를 구하는 것입니다. 

SUM 함수 -괄호 안의 숫자나, 셀범위의 합계를 나타내 줍니다. 

= SUM(number1,[number2],...) 

예) = SUM(1,2, 3) 

= SUM(A1,A2,A3,...) 

= SUM(A1:B10) 

SUMIF 함수 -단일 조건의 합계를 구합니다. 

= SUMIF(range, criteria, [sum_range])

range    조건을걸 범위입니다. 

criteria   조건

[sum_range] 실제 합을 구할 범위입니다. 

예) = SUMIF(A1:A10, "수학",B1:B10) 

= SUMIF(B1:B10, ">50",B1:B10) 

SUMIFS 함수 - 복수 조건의 합계를 구합니다. 

= SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

sum_range 실제 합을 구할 범위입니다. - 복수 조건일 경우는 실제 합을 구할 범위에 맨 앞에 오게 되는 것이 SUMIF와 다른 점입니다.

criteria_range1    조건을걸 첫번째 범위입니다. 

criteria1          criteria_range1 범위에 걸 조건입니다. 

criteria_range2    조건을걸 두번째 범위입니다. 

criteria2          criteria_range2 범위에 걸 조건입니다. 

예) = SUMIFS(B1:B10, A1:A10, "수학",B1:B10, ">50") 

세개 이상도 계속해서 criteria_range1, criteria1를 반복해서 적어주면 됩니다. 

그럼 직접 SUM 함수 예제부터 해보겠습니다. 

▲  SUM 함수를 이용해서 금액의 총합계를 구했습니다. 

=SUM(D3:D21)

▲  SUMIF 함수를 이용해 품목이 식비인 금액의 합계를 구했습니다. 

SUMIF 함수 

= SUMIF(range, criteria, [sum_range])

위 예처럼 criteria 부분을 특정 셀을 넣어 그 셀의 내용과 같은가 로 할 수 도 있고,

 =SUMIF(C3:C21,F7,D3:D21) F7의 셀을 보시면 "식비"라고 적혀있습니다.

 =SUMIF(C3:C21,"식비",D3:D21) 이와 같이 적어도 결과는 동일합니다. 

▲  응용입니다. 

SUMIF 함수 

= SUMIF(range, criteria, [sum_range])

F8,F9,F10 에 다른 품목의 이름도 준비물,교통비, 병원비를 적어준 후 

식비의 합계에 =SUMIF($C$3:$C$21,F7,$D$3:$D$21)로 작성후 

위그림의 화살표의 둥근점부터 화살표 끝까지 마우스로 드래그 해주면 위 그림처럼 

수식이 복사됩니다. 

주의 range와[sum_range] 범위를 $C$3:$C$21 처럼 범위를 절대참조해야 드래그 해도 범위가 변하지 않는다는 것을 기억해둡시다.

criteria는 F7로 절대참조를 하지말아야  준비물, 교통비, 병원비의 셀주소 F8,F9,F10으로 변하겠죠?

▲  SUMIFS 함수를 이용해 월간 각 품목별 합계를 구해보았습니다. 

SUMIFS 함수 - 복수 조건의 합계를 구합니다. 

= SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

=SUMIFS($D$3:$D$21,$C$3:$C$21,$F12,$B$3:$B$21,G$11)

$D$3:$D$21 - 실제 합을 구할 금액범위

$C$3:$C$21 - 첫번째 조건을 걸 범위 "품목"

$F12         - 첫번째 조건범위에 원하는 조건 "식비"로 써도 동일합니다. 

$B$3:$B$21 - 두번째 조건을 걸 기간범위 

G$11         - 두번째 조건범위에 원하는 조건 "2월"로 써도 동일합니다. 

G12셀에 이렇게 적어준 후 F15까지 드래그 하면 2월 3월 각 품목별 합계가 구해집니다. 

위 식의 절대참조 $위치를 잘 확인해 주셔서 작업하실 때 응용해 주시기 바랍니다. 

그리고 위와 같은 방법으로 평균을 구하는 함수 

AVERAGE, AVERAGEIF, AVERAGIFS 도 적용해 사용하실 수 있습니다.